OPTIONS LINESIZE=80;
TITLE1 'Nested Factorial Design  ';
TITLE2 'Factor A (MACHINE) : 3 Machine (A, B, C) fixed  ';
TITLE3 'Factor B (SPINDLE) : 2 Spindle for each machine (1, 2)  fixed';
TITLE4 'Var (COMPNT) : 4 Components from each spindle random  ';
DATA VARIBLTY;
/* @@ means a loop in reading input variable sequence */
INPUT MACHINE $ SPINDLE COMPNT  @@;
CARDS;
A 1 12 A 1  9 A 1 11 A 1 12
A 2  8 A 2  9 A 2 10 A 2  8
B 1 14 B 1 15 B 1 13 B 1 14
B 2 12 B 2 10 B 2 11 B 2 13
C 1 14 C 1 10 C 1 12 C 1 11
C 2 16 C 2 15 C 2 15 C 2 14
;
RUN;

/* Print the original data set                   */
PROC PRINT;
RUN;

/* Create Table & tabulate input data set        */
/* Nicety, but not absolutely necessary for      */
/* the analysis - you may skip                   */
PROC TABULATE;
     CLASS MACHINE SPINDLE;
     VAR COMPNT;
     LABEL COMPNT = 'COMPONENT (4 REPLICATES)';
     TABLE MACHINE*SPINDLE*COMPNT/CONDENSE;
     KEYLABEL SUM='Y(IJ)';
RUN;

/* General Linear Model (GLM)                    */
PROC GLM;
     CLASS MACHINE SPINDLE;
     MODEL  COMPNT = MACHINE SPINDLE(MACHINE);
     OUTPUT OUT = A2  P = YHAT  R = RESID;
RUN;

PROC PLOT DATA = A2;
     PLOT RESID*YHAT;
RUN;


/* Compute Normal Scores of input data, 'A2'     */
/* using cum. normal function/Residual           */
/* BLOM -> yi = þ-1(ri -3/8)/(n+1/4)              */
/*         ri = rank of the ith obs              */
PROC RANK DATA = A2 NORMAL = BLOM OUT = NPLOT2;
     VAR RESID;
     RANKS NSCORE;
RUN;

PROC PLOT DATA = NPLOT2;
     PLOT NSCORE*RESID;
RUN;